;ティラノスクリプトサンプルゲーム

*start

[cm  ]
[clearfix]
[start_keyconfig]


[bg storage="room.jpg" time="100"]

;メニューボタンの表示
@showmenubutton

;メッセージウィンドウの設定
[position layer="message0" left=20 top=400 width=920 height=200 page=fore visible=true]

;文字が表示される領域を調整
[position layer=message0 page=fore margint="45" marginl="50" marginr="70" marginb="60"]


;メッセージウィンドウの表示
@layopt layer=message0 visible=true

;キャラクターの名前が表示される文字領域
[ptext name="chara_name_area" layer="message0" color="white" size=24 x=50 y=410]

;上記で定義した領域がキャラクターの名前表示であることを宣言（これがないと#の部分でエラーになります）
[chara_config ptext="chara_name_area"]

;このゲームで登場するキャラクターを宣言
;akane
[chara_new  name="akane" storage="chara/akane/normal.png" jname="あかね"  ]
;キャラクターの表情登録
[chara_face name="akane" face="angry" storage="chara/akane/angry.png"]
[chara_face name="akane" face="doki" storage="chara/akane/doki.png"]
[chara_face name="akane" face="happy" storage="chara/akane/happy.png"]
[chara_face name="akane" face="sad" storage="chara/akane/sad.png"]


;yamato
[chara_new  name="yamato"  storage="chara/yamato/normal.png" jname="やまと" ]

#
话说，听说这里可以轻松制作游戏，我就过来看看[p]

结果一个人都没有啊。[p]
……[p]
回去吧。。。[p]

[font  size="30"   ]
#?
等一下————[p]
[resetfont  ]

#
谁！？[p]

;キャラクター登場
[chara_show  name="akane"  ]
#?
你好。[p]
我的名字叫茜。[p]
#あかね
难道说，你对视觉小说游戏的开发有兴趣？[p]

[glink  color="blue"  storage="scene1.ks"  size="20"  x="260"  width="400"  y="100"  text="はい。興味あります"  target="*selectinterest"  ]
[glink  color="blue"  storage="scene1.ks"  size="20"  x="260"  width="400"  y="170"  text="興味あります！"  target="*selectinterest"  ]
[glink  color="blue"  storage="scene1.ks"  size="20"  x="260"  width="400"  y="240"  text="どちらかと言うと興味あり"  target="*selectinterest"  ]
[s  ]
*selectinterest

[chara_mod  name="akane" face="happy"  ]
#あかね
哇。居然有兴趣，好开心啊。[p]
#
·····[p]
嘛，虽然确实有想做的念头，但是很难吧？[p]
我连编程都没碰过、、、[p]

[chara_mod name="akane" face="default"]

#あかね
正好有个好消息要告诉你这样的人[p]
想听吗？　你肯定想听吧？[p]
#
不，没兴趣
#あかね
[cm]
[font size=40]
[delay speed=160]
TyranoScript——[p]
[delay speed=30]
[resetfont]

#
····[p]
#あかね
使用TyranoScript的话，就能简单地制作出正式的文字冒险游戏哦。[p]
#
诶——这个倒是有点兴趣呢。[p]

[chara_mod  name="akane" face="happy"  ]
#あかね
真、真的！？[p]
只要玩这个游戏，就能了解TyranoScript的功能[p]
请务必陪我到最后哦[p]

首先，TyranoScript的特点是基于「HTML5」运行的哦[font color="red"][resetfont][p]


#
也、也就是说？[p]
#あかね
用TyranoScript制作的游戏可以在很多环境下运行！[p]
#
诶——那挺好的。[p]
好不容易做出来的话，当然想让更多人来玩嘛。[p]

#あかね
Windows的PC应用程序自不必说。[p]
也支持Mac的应用程序哦。[p]
还有，因为是HTML5，也可以作为浏览器游戏发布哦。[p]
可以嵌入网站让大家玩，能让人们轻松地体验游戏呢。[p]
支持所有主流浏览器，请放心。[p]
#
厉害啊……[p]

不过，最近智能手机普及了，来我网站的人里用智能手机访问的也变多了[p]
用手机玩不了吗？[p]

#あかね
用TyranoScript制作的游戏在智能手机上也能玩哦！[p]
iPhone、Android自不必说。iPad之类的平板也完全没问题。[p]
#
哦——[p]

#あかね
还可以做成应用在AppStore和GooglePlay上销售[p]
#
哦哦……说不定终于能摆脱贫困生活了[p]
#あかね
嘛，不做出有趣的游戏的话，也卖不出去就是了！[p]
#
唔……[p]

#あかね
那么，接下来试着切换场景吧[p]
我们移动到走廊去[p]
[bg  time="3000"  method="crossfade" storage="rouka.jpg"  ]

#
哦，移动到走廊了呢。[p]

#あかね
好冷啊？。快点回教室吧。[p]

[bg  time="1000" method="slide"  storage="room.jpg" ]
#
咦，刚才场景切换的方式有点不一样呢。[p]
#あかね
嗯。因为赶时间嘛。[p]
在TyranoScript中，可以添加各种各样的演出效果[p]
光是切换画面就有10种以上的演出可以使用哦。[p]
#
嗯。很方便[p]

#あかね
接下来试着改变一下消息的显示方式吧[p]
TyranoScript除了像现在这样的冒险游戏之外[r]
也可以制作像视觉小说那样全屏显示的游戏哦。[p]

#

;キャラクター非表示
[chara_hide name="akane"]


;メッセージを全画面に切り替え
[position layer="message0" left=20 top=40 width=920 height=560 page=fore visible=true ]

怎么样？想让玩家细细品读故事的话，这种方式很方便呢[l][r]
TyranoScript非常强大，可以实现灵活的表现形式。[l][cm]

[font size=40]文字のサイズを変更したり
[l][r]
[resetfont]
[font color="pink"]色を変更したり
[resetfont][l][r]

[ruby text=る]ル[ruby text=び]ビを[ruby text=ふ]振ることだって[ruby text=かん]簡[ruby text=たん]単にできます[l]
[cm]

;たて書きにする
[position vertical=true layer=message0 page=fore margint="45" marginl="0" marginr="70" marginb="60"]

像这样也可以用竖排方式来书写。[r][l]
即使是竖排，也可以使用和横排时相同的功能。[r][l]

;横書きに戻す
[position vertical=false]

还可以根据场景来区分使用横排和竖排[r][l]
那么，我切换回冒险游戏形式吧[p]

;メッセージボックスを元に戻す
[position layer="message0" left=20 top=400 width=920 height=200 page=fore visible=true]

@chara_show name="akane"

#akane
消息框也可以使用自己喜欢的图片哦[p]



[font color="0x454D51"]
[deffont color="0x454D51"]

;名前の表示位置も変更
[free name="chara_name_area" layer="message0"]

[position layer=message0 width=960 height=210 top=430 left=0]
[position layer=message0 page=fore frame="frame.png" margint="45" marginl="50" marginr="70" marginb="60" opacity=230 ]


;名前枠の設定
[ptext name="chara_name_area" layer="message0"  color="0xFAFAFA"  size=24 x=40 y=435]
[chara_config ptext="chara_name_area"]

怎么样？[p]
请根据游戏风格制作自己喜欢的设计吧[p]

还有，默认情况下存档和读档可以从画面右下角的按钮进行[p]
如果自定义窗口的话……[p]

;メニューボタン非表示
@hidemenubutton

;ロールボタン追加;;;;;;;;;;;;;;
	
[button name="role_button" role="skip" graphic="button/skip.png" enterimg="button/skip2.png" x=35 y=610]

;	オート
[button name="role_button" role="auto" graphic="button/auto.png" enterimg="button/auto2.png" x=110 y=610]

;	セーブ
[button name="role_button" role="save" graphic="button/save.png" enterimg="button/save2.png" x=185 y=610]

;ロード
[button name="role_button" role="load" graphic="button/load.png" enterimg="button/load2.png" x=260 y=610]

;クイックセーブ
[button name="role_button" role="quicksave" graphic="button/qsave.png" enterimg="button/qsave2.png" x=335 y=610]

;クイックロード
[button name="role_button" role="quickload" graphic="button/qload.png" enterimg="button/qload2.png" x=410 y=610]

;バックログ
[button name="role_button" role="backlog" graphic="button/log.png" enterimg="button/log2.png" x=485 y=610]

;メッセージウィンドウ非表示
[button name="role_button" role="window" graphic="button/close.png" enterimg="button/close2.png" x=560 y=610]

;フルスクリーン切替
[button name="role_button" role="fullscreen" graphic="button/screen.png" enterimg="button/screen2.png" x=635 y=610]

;メニュー呼び出し（※ロールボタンを使うなら不要）
[button name="role_button" role="menu" graphic="button/menu.png" enterimg="button/menu2.png" x=710 y=610]

;コンフィグ（※sleepgame を使用して config.ks を呼び出しています）
[button name="role_button" role="sleepgame" graphic="button/sleep.png" enterimg="button/sleep2.png" x=785 y=610 storage="config.ks"]

;タイトルに戻る
[button name="role_button" role="title" graphic="button/title.png" enterimg="button/title2.png" x=860 y=610]

;;ロールボタン追加終わり


像这样把游戏所需的功能放在画面上方也可以轻松实现哦[p]
这个叫做角色按钮，可以给按钮赋予特殊功能。[p]
标准配置有：[l]
存档、[l]
读档、[l][cm]
返回标题、
显示菜单、
隐藏消息、
跳过、
回顾日志、
全屏切换、
快速存档、
快速读档、
自动模式！
[p]

呼、呼[p]

#
没事吧？[p]
有这么多功能的话，做游戏应该不愁了吧[p]

#あかね
那么，当然也可以播放音乐哦[l][cm]
那么，要播放吗？[l][cm]

[link target=*playmusic]【１】うん。再生してください[endlink][r]
[link target=*noplay]【２】いや。今は再生しないで！[endlink]
[s]

*playmusic

[cm]
好，那就播放咯。[l]
@playbgm time="3000" storage=music.ogg loop=true
也可以一边逐渐淡入一边播放哦[l][cm]

@jump target="*common_bgm"

*noplay
[cm]
嗯。知道了。不播放呢。[l][cm]
下次再试试看吧[l][cm]

*common_bgm

啊，对了对了[l][cm]
像刚才那样用选项来让故事分支，也是很简单的哦。[l][cm]

#あかね
那么在这里，让别的角色登场吧[l][cm]
大和——[p]
[chara_show name="yamato"]

就像这样。很简单吧。[l][r]
角色可以让任意数量登场，试试看吧。[p]

#yamato
喂，我可以回去了吗？[l][cm]

#akane
啊，抱歉抱歉。谢谢你[l][cm]

[chara_hide name="yamato"]

#akane
TyranoScript的基本功能说明到这里就结束了[p]
感觉怎么样？[p]

#
嗯，感觉我自己也能做出来了[p]

#あかね
太好了！[p]
一开始的话，我建议你先试试TyranoScript官网上的教程！[p]
当然，这个游戏也是用TyranoScript做的，应该可以作为参考。[p]
请务必挑战一下游戏制作哦[p]
感谢你的游玩。[p]

最后我会显示一些对TyranoScript有帮助的信息链接
请确认一下哦。[p]

[cm]

*button_link

@layopt layer=message0 visible=false
@layopt layer=fix visible=false
[anim name="akane" left=600 time=1000]

;リンクボタンを表示
[glink text="ティラノビルダーの紹介" size=20 width=500 x=30 y=100 color=blue target=tyranobuilder ]
[glink text="制作事例" size=20 width=500 x=30 y=160 color=blue target=example ]
[glink text="応用テクニック" size=20 width=500 x=30 y=220 color=blue target=tech ]
[glink text="役に立つ情報源" size=20 width=500 x=30 y=280 color=blue target=info ]
[glink text="タグリファレンス" size=20 width=500 x=30 y=340 color=blue target=tagref ]

[s]

*tyranobuilder

[cm]
@layopt layer=message0 visible=true
@layopt layer=fix visible=true;
[font color-"red"]
「TyranoBuilder」
[resetfont]
这是一款免费的开发工具。[p]

[image layer=1 page=fore visible=true top=10 left=50 width=560 height=400  storage = builder.png]

这是一款可以通过图形化界面制作视觉小说的工具[p]
即使不擅长写脚本的人也能制作游戏，请务必试试看。[p]
[freeimage layer=1]

@jump target=button_link

[s]
*example
@layopt layer=message0 visible=true
@layopt layer=fix visible=true
至今为止，已经有很多游戏是用TyranoScript制作的。[p]
部分制作案例已经放在官网上了，有兴趣的话请去看看哦。[p]

[iscript]
window.open("http://tyrano.jp/home/example");
[endscript]

@jump target=button_link

[cm]
[s]

*tech
@layopt layer=message0 visible=true
@layopt layer=fix visible=true
在这个示例中，我只介绍了TyranoScript的一小部分功能[p]
如果想了解更多功能，可以下载完整的脚本[p]
推荐大家试着研究一下那些示例！[p]

[iscript]
window.open("http://tyrano.jp/home/demo");
[endscript]

@jump target=button_link


*info
@layopt layer=message0 visible=true
@layopt layer=fix visible=true
如果在使用TyranoScript时遇到不明白的地方[p]
可以在官方论坛提问，也可以参考Wiki等资料[p]
@jump target=button_link

*tagref
@layopt layer=message0 visible=true
@layopt layer=fix visible=true
标签都有详细的参考文档页面。[p]
请通过这个页面进一步掌握更详细的用法[p]

[iscript]
window.open("http://tyrano.jp/home/tag");
[endscript]

@jump target="*button_link"

[s]